<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                xmlns:tei="http://www.tei-c.org/ns/1.0" 
                xmlns:ct="http://www.comhartaighde.com/ns/1.0" 
                exclude-result-prefixes="tei ct"
                version="1.0">
    
    
<xsl:template match="tei:div[@type='citations']">
    <xsl:apply-templates select="tei:listBibl"/>
</xsl:template>

<xsl:template match="tei:listBibl">
    <xsl:apply-templates select="tei:head[@xml:lang='ga']"/>
    <xsl:for-each select="tei:bibl|tei:listBibl">
        <p id="{@xml:id}">
            <xsl:apply-templates select="text()|tei:title|tei:settlement|tei:repository|tei:msDesc|tei:idno|tei:monogr|tei:analytic"/>
        </p>
    </xsl:for-each>
</xsl:template>
    
<xsl:template match="tei:listBibl[@type='manuscripts']">
    <xsl:apply-templates select="tei:head[@xml:lang='ga']"/>
    <xsl:for-each select="tei:bibl|tei:listBibl">
        <!-- inneachar na lámhscríbhinní a aschur gan p-chlib bhreise-->
        <xsl:apply-templates select="text()|tei:title|tei:settlement|tei:repository|tei:msDesc|tei:idno|tei:monogr|tei:analytic"/>
    </xsl:for-each>
</xsl:template>

<xsl:template match="tei:listBibl/tei:head[@xml:lang='ga']">
    <h3><xsl:apply-templates select="text()|tei:title"/></h3>
</xsl:template> 
    
<xsl:template match="tei:settlement">
    <h4 id="{../@xml:id}"><xsl:value-of select="."/></h4>
</xsl:template>
    
<xsl:template match="tei:repository">
    <h5><xsl:value-of select="."/></h5>
</xsl:template>

<xsl:template match="tei:monogr|analytic">
    <xsl:apply-templates select="text()|tei:author|tei:editor|tei:date|tei:title|tei:reprint|tei:pubPlace|tei:publisher|tei:biblScope"/>
</xsl:template>
    
<xsl:template match="tei:author|tei:editor|tei:addName|tei:date|tei:reprint|tei:pubPlace|tei:publisher|tei:biblScope">
    <xsl:value-of select="."/>
</xsl:template>
    
<xsl:template match="tei:msDesc">
    <xsl:for-each select="tei:msIdentifier/tei:idno">
        <p>
            <xsl:apply-templates select="text()|tei:title|tei:placeName|tei:persName|tei:ref|tei:lb|tei:emph|tei:hi|tei:foreign"/>
        </p>
    </xsl:for-each>
</xsl:template>

    
</xsl:stylesheet>